AutoHotkey

キーボードカスタマイズソフト
http://www.autohotkey.com/

Insertキー押し間違いがあまりにも多いので無効にするため導入。
設定簡単で、マクロや式も使えて便利っぽい

とりあえず、Insert無効と現在時刻挿入、Winキー+hjklでvi移動、Winキー+矢印でウィンドウ移動、同じウィンドウクラス切り替え、常に手前に表示するのを入れてみた。

#h::left    ;Win+Hに←キーを割り当て
#j::down    ;Win+Jに↓キーを割り当て
#k::up      ;Win+Kに↑キーを割り当て
#l::right   ;Win+Lに→キーを割り当て

Ins::return ; Insertキーの無効

;; now--で日付挿入
::now--::
FormatTime, TimeStr,, yyyy/MM/dd hh:mm:ss
Clipboard=%TimeStr%
Send,^v
Return


;;同じウィンドウクラスのウィンドウを切り替える(Alt+Ctrl+Tab)
!^Tab::
  WinGetClass, className, A
  WinActivateBottom, ahk_class %className%
  return

;; Window Move
WinMoveStep(XD,YD) {
	WinGet,win_id,ID,A
	WinGetPos,x,y,,,ahk_id %win_id%
	Step := 24
	x := x + (XD * Step)
	y := y + (YD * Step)
	WinMove,ahk_id %win_id%,,%x%,%y%
	return
}
#Left::WinMoveStep(-1,0)
#Right::WinMoveStep(1,0)
#Up::WinMoveStep(0,-1)
#Down::WinMoveStep(0,1)

; --------------------------------------------------
; Window Size
WinSizeStep(XD,YD) {
	WinGet,win_id,ID,A
	WinGetPos,,,w,h,ahk_id %win_id%
	Step := 24
	w := w + (XD * Step)
	h := h + (YD * Step)
	WinMove,ahk_id %win_id%,,,,%w%,%h%
	return
}
+#Left::WinSizeStep(-1,0)
+#Right::WinSizeStep(1,0)
+#Up::WinSizeStep(0,-1)
+#Down::WinSizeStep(0,1)

;;常に手前に表示 (トグル) 
#F12::winset, alwaysontop, toggle, A